使用CMake预编译的头文件

c++ visual-studio gcc cmake precompiled-headers

57026 观看

13回复

我在网上看到了一些关于在CMake中对预编译头文件进行黑客攻击的一些(旧)帖子。它们看起来都有点遍布整个地方,每个人都有自己的方式。目前最好的方法是什么?

作者: Glutinous 的来源 发布者: 2019 年 9 月 13 日

回应 (13)


73

有一个名为“Cotire”的第三方CMake模块可以自动使用基于CMake的构建系统的预编译头,并且还支持统一构建。

作者: sakra 发布者: 23.03.2012 11:46

34

我使用以下宏来生成和使用预编译头:

MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "${CMAKE_CURRENT_BINARY_DIR}/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_OUTPUTS "${PrecompiledBinary}")
    SET_SOURCE_FILES_PROPERTIES(${Sources}
                                PROPERTIES COMPILE_FLAGS "/Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_DEPENDS "${PrecompiledBinary}")  
    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

假设你有一个带有所有源文件的变量$ {MySources},你想要使用的代码就是

ADD_MSVC_PRECOMPILED_HEADER("precompiled.h" "precompiled.cpp" MySources)
ADD_LIBRARY(MyLibrary ${MySources})

代码在非MSVC平台上仍然可以正常运行。漂亮整齐 :)

作者: larsmoa 发布者: 04.09.2009 03:46

20

这是一个代码片段,允许您为项目使用预编译头。将以下内容添加到您的CMakeLists.txt中,myprecompiledheadersmyproject_SOURCE_FILES根据需要进行替换:

if (MSVC)

    set_source_files_properties(myprecompiledheaders.cpp
        PROPERTIES
        COMPILE_FLAGS "/Ycmyprecompiledheaders.h"
        )
    foreach( src_file ${myproject_SOURCE_FILES} )
        set_source_files_properties(
            ${src_file}
            PROPERTIES
            COMPILE_FLAGS "/Yumyprecompiledheaders.h"
            )
    endforeach( src_file ${myproject_SOURCE_FILES} )
    list(APPEND myproject_SOURCE_FILES myprecompiledheaders.cpp)
endif (MSVC)
作者: Dave Hillier 发布者: 03.11.2008 11:47

13

我最终使用了larsm宏的改编版本。对pch路径使用$(IntDir)可以使调试和发布版本的预编译头分开。

MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "$(IntDir)/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_OUTPUTS "${PrecompiledBinary}")
    SET_SOURCE_FILES_PROPERTIES(${Sources}
                                PROPERTIES COMPILE_FLAGS "/Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_DEPENDS "${PrecompiledBinary}")  
    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

ADD_MSVC_PRECOMPILED_HEADER("stdafx.h" "stdafx.cpp" MY_SRCS)
ADD_EXECUTABLE(MyApp ${MY_SRCS})
作者: jari 发布者: 02.06.2010 09:28

12

改编自Dave,但效率更高(设置目标属性,而不是每个文件):

if (MSVC)
   set_target_properties(abc PROPERTIES COMPILE_FLAGS "/Yustd.h")
   set_source_files_properties(std.cpp PROPERTIES COMPILE_FLAGS "/Ycstd.h")
endif(MSVC)
作者: martjno 发布者: 09.07.2010 08:26

7

如果你不想推倒重来,只使用两种Cotire作为顶端回答暗示或简单的一个- 的cmake-预编译头 在这里。要使用它只需包含模块并调用:

include( cmake-precompiled-header/PrecompiledHeader.cmake )
add_precompiled_header( targetName StdAfx.h FORCEINCLUDE SOURCE_CXX StdAfx.cpp )
作者: Roman Kruglov 发布者: 02.02.2017 02:44

4

恕我直言,最好的方法是为整个项目设置PCH,如martjno建议的那样,结合在需要时忽略PCH的能力(例如生成的源):

# set PCH for VS project
function(SET_TARGET_PRECOMPILED_HEADER Target PrecompiledHeader PrecompiledSource)
  if(MSVC)
     SET_TARGET_PROPERTIES(${Target} PROPERTIES COMPILE_FLAGS "/Yu${PrecompiledHeader}")
     set_source_files_properties(${PrecompiledSource} PROPERTIES COMPILE_FLAGS "/Yc${PrecompiledHeader}")
  endif(MSVC)
endfunction(SET_TARGET_PRECOMPILED_HEADER)

# ignore PCH for a specified list of files
function(IGNORE_PRECOMPILED_HEADER SourcesVar)
  if(MSVC)  
    set_source_files_properties(${${SourcesVar}} PROPERTIES COMPILE_FLAGS "/Y-")
  endif(MSVC)
endfunction(IGNORE_PRECOMPILED_HEADER)

因此,如果您有一些目标MY_TARGET,以及生成的源列表IGNORE_PCH_SRC_LIST,您只需执行以下操作:

SET_TARGET_PRECOMPILED_HEADER(MY_TARGET stdafx.h stdafx.cpp)
IGNORE_PRECOMPILED_HEADER(IGNORE_PCH_SRC_LIST)

这种方法经过测试,效果很好。

作者: Vram Vardanian 发布者: 16.04.2015 10:38

4

使用cmake和Visual Studio 2015的预编译头的使用示例

“stdafx.h”,“stdafx.cpp” - 预编译的头名。

将以下内容放在根cmake文件中。

if (MSVC)
    # For precompiled header.
    # Set 
    # "Precompiled Header" to "Use (/Yu)"
    # "Precompiled Header File" to "stdafx.h"
    set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Yustdafx.h /FIstdafx.h")
endif()

将以下内容放在项目cmake文件中。

“src” - 包含源文件的文件夹。

set_source_files_properties(src/stdafx.cpp
    PROPERTIES
    COMPILE_FLAGS "/Ycstdafx.h"
)
作者: Maks 发布者: 13.05.2016 05:27

0

那么当每次更改任何项目文件中的单行时,在四核计算机上构建需要10多分钟时,它会告诉您为Windows添加预编译头的时间。在* nux上我会使用ccache而不用担心。

我在我的主应用程序和它使用的一些库中实现了。它在这一点上很有用。还需要做的一件事是你必须创建pch源文件和头文件,并在源文件中包含你想要预编译的所有头文件。我用MFC做了12年,但我花了几分钟时间才回想起......

作者: John M Drescher 发布者: 22.04.2009 04:03

0

最干净的方法是将预编译选项添加为全局选项。在vcxproj文件中,这将显示为,<PrecompiledHeader>Use</PrecompiledHeader>而不是为每个单独的文件执行此操作。

然后,您需要将Create选项添加到StdAfx.cpp。以下是我如何使用它:

MACRO(ADD_MSVC_PRECOMPILED_HEADER SourcesVar)
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /YuStdAfx.h")
    set_source_files_properties(StdAfx.cpp
        PROPERTIES
        COMPILE_FLAGS "/YcStdAfx.h"
        )
    list(APPEND ${${SourcesVar}} StdAfx.cpp)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

file(GLOB_RECURSE MYDLL_SRC
    "*.h"
    "*.cpp"
    "*.rc")

ADD_MSVC_PRECOMPILED_HEADER(MYDLL_SRC)
add_library(MyDll SHARED ${MYDLL_SRC})

这是经过测试并适用于MSVC 2010并将创建一个MyDll.pch文件,我不打算使用什么文件名,所以我没有做任何努力来指定它。

作者: uncletall 发布者: 07.01.2015 08:33

0

由于预编译头选项不适用于rc文件,我需要调整jari提供的宏。

#######################################################################
# Makro for precompiled header
#######################################################################
MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "$(IntDir)/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    # generate the precompiled header
    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Zm500 /Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                            OBJECT_OUTPUTS "${PrecompiledBinary}")

    # set the usage of this header only to the other files than rc
    FOREACH(fname ${Sources})
        IF ( NOT ${fname} MATCHES ".*rc$" )
            SET_SOURCE_FILES_PROPERTIES(${fname}
                                        PROPERTIES COMPILE_FLAGS "/Zm500 /Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                                    OBJECT_DEPENDS "${PrecompiledBinary}")
        ENDIF( NOT ${fname} MATCHES ".*rc$" )
    ENDFOREACH(fname)

    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

编辑:这个预编译头的使用将我的主项目的总体构建时间从4分30秒减少到1分40秒。这对我来说真是件好事。在预编译头中只有像boost / stl / Windows / mfc这样的头文件。

作者: schorsch_76 发布者: 08.09.2016 09:42

0

CMake刚刚获得了对PCH的支持,它应该在2019-10-01即将发布的3.16版本中提供:

https://gitlab.kitware.com/cmake/cmake/merge_requests/3553

  target_precompile_headers(<target>
    <INTERFACE|PUBLIC|PRIVATE> [header1...]
    [<INTERFACE|PUBLIC|PRIVATE> [header2...] ...])

目前正在讨论支持在目标之间共享PCH:https://gitlab.kitware.com/cmake/cmake/issues/19659

https://blog.qt.io/blog/2019/08/01/precompiled-headers-and-unity-jumbo-builds-in-upcoming-cmake/提供了一些额外的背景(动机,数字)。

作者: janisozaur 发布者: 29.08.2019 07:13

-15

甚至不去那里。预编译头文件意味着每当其中一个标头发生更改时,您必须重建所有内容。如果你有一个实现这个的构建系统,那你很幸运。通常情况下,您的构建将失败,直到您意识到您更改了正在预编译的内容,因此您需要进行完全重建。你可以通过预编译你绝对肯定不会改变的标题来避免这种情况,但是你也放弃了很大一部分速度增益。

另一个问题是,在您使用预编译头文件的许多地方,您的命名空间会受到您不知道或不关心的各种符号的污染。

作者: Dirk Groeneveld 发布者: 07.10.2008 09:23
32x32